サイトについて      連絡先   検索

エクセル 2016 IF 関数を複数条件に対応する

はじめに

エクセル 2016 IF 関数を複数条件に対応する方法を紹介します。

複数条件にはいろいろあります。ここでは次の方法を紹介します。

IF 関数の基本的な使い方については「IF 関数」をご覧ください。

3 つ以上に分岐する

IF 関数がどのようなものか簡単に説明すると次のようになります。

=IF(判定, TRUE の処理, FALSE の処理)

IF 関数の「TRUE の処理」や「FALSE の処理」に別の IF 関数を入れ子にして 3 つ以上の分岐ができます。ここでは FALSE の処理を入れ子にする例を紹介します。次の 3 つの条件を例にして紹介します。

「0 より大きい値を「プラス」と表示する」を IF 関数にすると次のようになります。

=IF(B3>0,"プラス"

「0 より小さい値を「マイナス」と表示する」を IF 関数にすると次のようになります。

IF(B3<0,"マイナス"

1 つ目の IF 関数の FALSE の処理に、2 つ目の条件の IF 関数を入力して組み合わせます。

=IF(B3>0,"プラス",IF(B3<0,"マイナス"

「それ以外の値 (0) を「ゼロ」と表示する」を最後の IF 関数の FALSE の処理に加えると次のようになります。これで 3 つの条件に対応できます。

=IF(B3>0,"プラス",IF(B3<0,"マイナス","ゼロ"))
6

ポイントは IF 関数の TRUE の処理が 1 つの分岐になります。FALSE の処理に次の IF 関数を入力して 2 つ目の分岐、またその FALSE の処理に次の IF 関数を入力して 3 つ、4 つと IF 関数をつなげて分岐を増やせます。最後の FALSE の処理にそれ以外の値を指定します。

IF1(条件1,処理1, IF2(条件2,処理2, IF3(・・・,それ以外の処理)

複数条件の全てを満たしたときに処理をする

値が 80 以上で 100 以下のときに「合格」と表示するように、複数の条件を全て満たしているか判定するには「AND 関数」を使用します。

次のように条件をカンマ区切りにして 3 つでも 4 つでも複数条件に対応できます。

=AND(条件1, 条件2)
=AND(条件1, 条件2, 条件3)

セル「B3」の値が 80 以上で 100 以下のときに「合格」と表示するには次のようにします。

=IF(AND(B3>=80,B3<=100),"合格","")
7

名前が「エクセル」でバージョンが「2016」で値が 80 以上のときに「合格」と表示するには次のようにします。

=IF(AND(B3="エクセル",C3=2016,D3>=80),"合格","")
8

複数条件のどれか一つを満たしたときに処理をする

名前が「エクセル」または「ワード」のときに「合格」と表示するように、複数の条件の一つでも満たしているか判定するには「OR 関数」を使用します。

次のように条件をカンマ区切りにして 3 つでも 4 つでも複数条件に対応できます。

=OR(条件1, 条件2)
=OR(条件1, 条件2, 条件3)

セル「B3」が「エクセル」または「ワード」のときに「合格」と表示するには次のようにします。

=IF(OR(B3="エクセル",B3="ワード"),"合格","")
9

名前が「エクセル」またはバージョンが「2016」または値が 80 以上のときに「合格」と表示するには次のようにします。

=IF(OR(B3="エクセル",C3=2016,D3>=80),"合格","")
10

関連ページ