更新日:、 作成日:

エクセル AVERAGEIF 関数:条件に一致する平均を求める

はじめに

エクセルの AVERAGEIF 関数の使い方を紹介します。

AVERAGEIF 関数は条件に一致するセルの平均を求めます。複数条件に対応した上位互換の「AVERAGEIFS 関数」があります。

=AVERAGEIF(A1:A3,"<>0") のようにして、0 以外の数値の平均を計算できます。

数値の範囲や文字列などを条件にして平均を求めたいときに使用します。

文字列かどうかや空白など、特定の値を条件にする方法は「COUNTIF 関数」にまとめています。

AVERAGEIF 関数の引数

AVERAGEIF(範囲, 条件)
範囲の中で条件を満たすセルの平均を求めます。

AVERAGEIF(範囲, 条件, 平均範囲)
範囲の中で条件を満たすセルと対応する平均範囲の平均を求めます。

引数「範囲」引数「条件」の対象になるセルの範囲を指定します。配列不可
引数「条件」平均する条件を比較演算子やワイルドカードを使って指定します。スピル化
引数「平均範囲」省略できます。省略すると引数「範囲」が平均範囲になります。
この範囲の平均を求めます。
配列不可

スピル化:セルの範囲や配列を指定すると結果が「スピル」します。

配列不可:配列を指定できません。セルの範囲のみ指定できます。

引数「条件」

使用できる比較演算子には次のものがあります。

演算子 演算名 使用例 結果
=等しい"=2"2 と同じ
<>等しくない"<>2"2 以外
>大きい">2"2 より大きい
<小さい"<2"2 より小さい
>=以上">=2"2 以上
<=以下"<=2"2 以下

使用できるワイルドカードには次のものがあります。

パターン 説明 使用例 一致例
*任意の長さの文字"あ*"あ, あい, あいう
?任意の 1 文字"あ?"あい, あか, あき
~ワイルドカードの文字 * ? を検索する"あ~?~*"あ?*

使い方

AVERAGEIF 関数の使い方を紹介します。

値が 100 以上の平均を求める

値が 100 以上の平均を求めます。

=AVERAGEIF(B3:B6,">=100")
15

セルの値以上の平均を求める

値がセル「C3」以上の平均を求めます。

=AVERAGEIF(B3:B6,">="&C3)

"比較演算子"&セル名 のようにしてセル参照を使用できます。

19

日付が 2000/1/1 ~ の平均を求める

日付が 2000/1/1 以降の値の平均を求めます。

=AVERAGEIF(C3:C6,">="&DATE(2000,1,1),B3:B6)

日付を入力するには「DATE 関数」を使用します。

20

名前がエクセルの平均を求める

名前が エクセル の値の平均を求めます。

=AVERAGEIF(B3:B6,"=エクセル",C3:C6)
16

特定の文字が入っているセルの平均を求める

ワイルドカードを使用して、名前に ワード が入っている値の平均を求めます。

=AVERAGEIF(B3:B6,"=*ワード*",C3:C6)
=AVERAGEIF(B3:B6,"=ワード*",C3:C6)
=AVERAGEIF(B3:B6,"=*ワード",C3:C6)

名前が ワード で始まる値は "=ワード*" のように入力します。

名前が ワード で終わる値は "=*ワード" のように入力します。

21

解説

複数条件に対応した上位互換である「AVERAGEIFS 関数」があります。通常はそちらを使用します。

引数「数値」や引数「平均範囲」が日付なら、日付の実際の値は数値なのでその値を計算します。

引数「範囲」や引数「平均範囲」に文字列や TRUE や FALSE、空のセルが含まれるときは、そのセルを無視します。

引数「範囲」や引数「平均範囲」に 1 つも有効な数値が含まれていないときはエラー #DIV/0! になります。

引数「範囲」に条件に一致するセルが 1 つもないときはエラー #DIV/0! になります。

引数「平均範囲」の範囲は、必ず引数「範囲」と同じ大きさになります。次の実際の平均範囲は C3:C6 です。

18

引数「条件」に比較演算子を入力するときは "" で囲んで入力します。

引数「条件」に比較演算子を省略した "エクセル""=エクセル" と同じ条件になります。

引数「条件」にセル参照を入力するときは "比較演算子"&セル名 のように & で比較演算子とセル名を結合します。

引数「条件」に日付を入力するときは「DATE 関数」を使用します。時刻を入力するときは「TIME 関数」を使用します。"="&DATE(2000,1,1) のように & で比較演算子と結合します。

引数「条件」は大文字と小文字を区別しません。 "=ABC" としたときは abc などと一致します。