更新日:、 作成日:

エクセル 日付の日数計算をする

はじめに

365202120192016:対応

エクセルの日付を引き算した日数を計算をする方法を紹介します。

=DAYS(終了日,開始日) のようにして、日数を取得できます。

=DATEDIF(開始日,終了日,"M") のようにして、満月数を取得できます。

=DATEDIF(開始日,終了日,"Y") のようにして、満年数を取得できます。

初日を含むように満ではない日数や月数を計算したり、何日経過したのかを計算できます。

年齢を計算するには「年齢計算する方法」をご覧ください。
時間を計算するには「時間計算する方法」をご覧ください。
月末や数日後の日付を入力するには「日付を自動で入力する」をご覧ください。

日付の日数を計算する

開始日から終了日までの日数や月数などを計算する方法を紹介します。

日数

DAYS 関数」や「DATEDIF 関数」を使用したり、日付を引き算して日数を計算します。

=DAYS(C3,B3)
=DATEDIF(B4,C4,"D")
=C5-B5
  • DAYS 関数:時間を無視します。
  • DATEDIF 関数:時間を無視します。開始日が終了日を超えるときはエラー #NUM! になります。
  • 引き算:時間を含めた結果になるので、日時のときは時間を表す小数が付きます。

開始日と終了日が同じ日のときに 1 日にするには、結果に 1 を足します。

=DAYS(C6,B6)+1
3

休日を除いた営業日数

NETWORKDAYS.INTL 関数」を使用して、開始日から終了日までの休日を除いた営業日数を計算します。第 3 引数に休みの曜日を入力して、第 4 引数に休日を入力できます。詳しくは関数のページをご覧ください。

=NETWORKDAYS.INTL(B3,C3,"0000011")
41

週数

日数を 7 で割って日付の満週数を計算します。「INT 関数」を使用して小数を切り捨てます。

=INT(DAYS(C3,B3)/7)

当日 ~ 6 日目までを 0 週、7 日目から 1 週として計算するには、日数に 1 を足してから計算します。

=INT((DAYS(C4,B4)+1)/7)
40

月数

DATEDIF 関数」を使用して、日付の満月数を計算します。

=DATEDIF(B3,C3,"M")

満ではなく日数を考慮した月数を計算するには、結果に 1 を足します。

=DATEDIF(B4,C4,"M")+1

日数を無視して月数を計算するには「YEAR, MONTH, DAY 関数」を使用します。年に 12 を掛けて月数にして計算します。

=(YEAR(C5)*12+MONTH(C5))-(YEAR(B5)*12+MONTH(B5))
14

1 年未満の月数 (年齢の何ヵ月)

DATEDIF 関数」を使用して、日付の 1 年未満の満月数を計算します。これが年齢の何ヵ月になります。

=DATEDIF(B3,C3,"YM")
16

年数

DATEDIF 関数」を使用して、日付の満年数を計算します。これが年齢の何歳になります。

=DATEDIF(B3,C3,"Y")

満ではなく日数を考慮した年数を取得するには、結果に 1 を足します。

=DATEDIF(B4,C4,"Y")+1

日数を無視して月数を考慮した年数を取得するには「YEAR, MONTH, DAY 関数」を使用します。年に 12 を掛けて月数にして計算します。

=INT(((YEAR(C5)*12+MONTH(C5))-(YEAR(B5)*12+MONTH(B5)))/12)

月数を無視して年数を取得するには「YEAR 関数」を使用します。

=YEAR(C6)-YEAR(B6)
13

1 年未満の満日数

DATEDIF 関数」を使用して、日付の 1 年未満の満日数を計算します。

=DATEDIF(B3,C3,"YD")

満日数が 365 (うるう年なら 366) になるごとに結果が 0 に戻ります。

17

1 ヶ月未満の満日数

DATEDIF 関数」を使用して、日付の 1 ヶ月未満の満日数を計算します。

=DATEDIF(B3,C3,"MD")

日がその日になるごとに結果が 0 に戻ります。

18