更新日:、 作成日:

エクセル 文字数をカウントする

はじめに

365202120192016:対応

エクセルの文字数をカウントする方法を紹介します。

=LEN(A1) のようにして、セルの文字数をカウントできます。数値の桁数もカウントできます。

=(LEN(A1)-LEN(SUBSTITUTE(A1,"A","")))/LEN("A") のようにして、A と同じ文字が何文字あるかをカウントできます。

=SUM(LEN(A1:A3)) のようにして、セルの範囲の文字数の合計をカウントできます。

全角と半角の文字数や、数字や日付の文字数をカウントできます。

文字列を抽出するには「文字列を抽出する」をご覧ください。

文字数をカウントする

文字数をカウントするには「LEN 関数」を使用します。

文字数をカウントする

セル「B3」の文字数をカウントします。

=LEN(B3)
11

桁数

同じようにして数値の桁数をカウントできます。

=LEN(B3)
12

小数が含まれているときに整数の桁数をカウントします。「INT 関数」を使用して小数を切り捨てできます。

=LEN(INT(B3))
13

全角と半角

LENB 関数」を使用して、全角なら 2、半角なら 1 を取得できます。

全角の文字数を取得するには LENB - 文字数 のように入力します。

半角の文字数を取得するには LENB - (LENB - 文字数) * 2 のように入力します。

=LENB(B3)-LEN(B3)
=LENB(B4)-(LENB(B4)-LEN(B4))*2
14

Unicode 文字が含まれているときは正しくカウントできません。

Unicode 文字

LEN 関数」と「LENB 関数」は Unicode 文字を正しくカウントできません。

Unicode 専用文字 1 を、「LENB 関数」でも 1 を取得します。

Unicode サロゲートペア文字 𩸽😃2 を、「LENB 関数」でも 2 を取得します。

=LEN(B3)
LENB(B3)
15

セルの範囲の文字数をカウントする

セルの範囲の文字数を取得するには「スピル」を使用します。

=SUM(LEN(B2:B4))
9

LEN 関数」の中にセルの範囲を入力しているのでスピルします。

各セルの文字数を「SUM 関数」で合計します。

スピルは 365 または 2021 から使用できます。

数式を Ctrl + Shift + Enter で確定すると「配列数式」になり、すべてのバージョンで使用できます。

同じ文字をカウントする

AABB の中に A が何文字あるかカウントする方法を紹介します。

=(C4-D4)/LEN("A")
=(LEN(B4)-LEN(SUBSTITUTE(B4,"A","")))/LEN("A")
=(C10-D10)/LEN("AA")
=(LEN(B10)-LEN(SUBSTITUTE(B10,"AA","")))/LEN("AA")
17

数式の解説をします。「LEN 関数」を使用して文字数を取得します。

SUBSTITUTE 関数」を使用して、A と同じ文字を削除します。

文字数 - 削除後の文字数 のように入力して、A と同じ文字の数をカウントできます。

AA のように複数の文字をカウントするには、それを 1 文字としてカウントしたいのでその文字数で割ります。

数字や日付の文字数をカウントする

数字や日付の文字数をカウントするときは、セルの書式設定の表示形式が適用される前の値をカウントします。

カンマ区切りの数字 1,000 の実際の値は 1000 です。

日付 2000/1/1 の実際の値は 36526 です。

カンマ区切りや日付のままカウントするには「TEXT 関数」を使用して文字列に変換してからカウントします。

=LEN(TEXT(B3,"#,##0"))
=LEN(TEXT(B5,"yyyy/m/d"))
18

セルに設定されている表示形式を取得するには、セルの書式設定のユーザー定義をコピーします。日本語が含まれているときは "" で囲まれているのでそれを削除します。

user-format

表示形式について詳しくは次をご覧ください。

特定の文字が入っているセルをカウントする

特定の文字が入っているセルの数をカウントするには「COUNTIF 関数」を使用します。

セル「B2」~「B5」に A の文字が入っているセルの数をカウントします。

=COUNTIF(B2:B5,"*A*")
9

文字列を "*文字*" で囲みます。

大文字と小文字は区別しません。

文字列かどうかや空白など、特定の値を条件にする方法は「COUNTIF 関数」にまとめています。