更新日:、 作成日:

エクセル SUMIF 関数:条件に一致する合計を求める

はじめに

エクセルの SUMIF 関数の使い方を紹介します。

SUMIF 関数は条件に一致するセルの合計を求めます。複数条件に対応した上位互換の「SUMIFS 関数」があります。

=SUMIF(A1:A3,"=エクセル",B1:B3) のようにして、セルの値が「エクセル」の合計を計算できます。

=SUMIF(A1:A3,"=*エクセル*",B1:B3) のようにして、「エクセル」が入っているセルの合計を計算できます。

=SUMIF(A1:A3,"=*",B1:B3) のようにして、文字列のセルの合計を計算できます。

数値の範囲や文字列などを条件にして合計を求めたいときに使用します。

文字列かどうかや空白など、特定の値を条件にする方法は「COUNTIF 関数」にまとめています。

SUMIF 関数の引数

SUMIF(範囲, 条件)
範囲の中で条件を満たすセルの合計を求めます。

SUMIF(範囲, 条件, 合計範囲)
範囲の中で条件を満たすセルと対応する合計範囲の合計を求めます。

引数「範囲」引数「条件」の対象になるセルの範囲を指定します。配列不可
引数「条件」合計する条件を比較演算子やワイルドカードを使って指定します。スピル化
引数「合計範囲」省略できます。省略すると引数「範囲」が合計範囲になります。
この範囲の合計を求めます。
配列不可

スピル化:セルの範囲や配列を指定すると結果が「スピル」します。

配列不可:配列を指定できません。セルの範囲のみ指定できます。

引数「条件」

使用できる比較演算子には次のものがあります。

演算子 演算名 使用例 結果
=等しい"=2"2 と同じ
<>等しくない"<>2"2 以外
>大きい">2"2 より大きい
<小さい"<2"2 より小さい
>=以上">=2"2 以上
<=以下"<=2"2 以下

使用できるワイルドカードには次のものがあります。

パターン 説明 使用例 一致例
*任意の長さの文字"あ*"あ, あい, あいう
?任意の 1 文字"あ?"あい, あか, あき
~ワイルドカードの文字 * ? を検索する"あ~?~*"あ?*

使い方

SUMIF 関数の使い方を紹介します。

値が 100 以上の合計を求める

値が 100 以上の合計を求めます。

=SUMIF(B3:B6,">=100")
18

セルの値以上の合計を求める

値がセル「C3」以上の合計を求めます。

=SUMIF(B3:B6,">="&C3)

"比較演算子"&セル名 のようにしてセル参照を使用できます。

19

日付が 2000/1/1 ~ の合計を求める

日付が 2000/1/1 以降の値の合計を求めます。

=SUMIF(C3:C6,">="&DATE(2000,1,1),B3:B6)

日付を入力するには「DATE 関数」を使用します。

20

名前がエクセルの合計を求める

名前が エクセル の値の合計を求めます。

=SUMIF(B3:B6,"=エクセル",C3:C6)
21

特定の文字が入っているセルの合計を求める

ワイルドカードを使用して、名前に ワード が入っている値の合計を求めます。

=SUMIF(B3:B6,"=*ワード*",C3:C6)
=SUMIF(B3:B6,"=ワード*",C3:C6)
=SUMIF(B3:B6,"=*ワード",C3:C6)

名前が ワード で始まる値は "=ワード*" のように入力します。

名前が ワード で終わる値は "=*ワード" のように入力します。

24

解説

複数条件に対応した上位互換である「SUMIFS 関数」があります。通常はそちらを使用します。

引数「数値」や引数「合計範囲」が日付なら、日付の実際の値は数値なのでその値を計算します。

引数「数値」や引数「合計範囲」に文字列や TRUE や FALSE、空のセルが含まれるときは、そのセルを 0 として計算します。

引数「合計範囲」の範囲は、必ず引数「範囲」と同じ大きさになります。次の実際の合計範囲は C3:C6 です。

23

引数「条件」に比較演算子を入力するときは "" で囲んで入力します。

引数「条件」に比較演算子を省略した "エクセル""=エクセル" と同じ条件になります。

引数「条件」にセル参照を入力するときは "比較演算子"&セル名 のように & で比較演算子とセル名を結合します。

引数「条件」に日付を入力するときは「DATE 関数」を使用します。時刻を入力するときは「TIME 関数」を使用します。"="&DATE(2000,1,1) のように & で比較演算子と結合します。

引数「条件」は大文字と小文字を区別しません。 "=ABC" としたときは abc などと一致します。

文字列の合計

文字列の中の数字の合計を求めるには「SUM 関数」をご覧ください。