サイトについて      連絡先   検索

エクセル 2013 COUNTIF 関数:条件に一致するセルを数える

はじめに

エクセル 2013 の COUNTIF 関数の使い方を紹介します。

COUNTIF 関数は条件に一致するセルを数えます。

「0」以外のセルや特定の文字列が入ったセルを数えたいときに使用します。

AND 関数」や「OR 関数」を使用して複数の条件に一致するセルを数えられます。

  • 目次
    • 構文
    • 使用例
    • 解説
    • 複数の条件を指定する

構文

COUNTIF(範囲, 条件)
範囲の中で条件を満たすセルの数を数えます。

引数「範囲」引数「条件」の対象になるセルの範囲を指定します。
引数「条件」数える条件を比較演算子やワイルドカードを使って指定します。

引数「条件」に使用できる比較演算子には次のものがあります。

演算子 演算名 使用例 結果
=等しい"=2"2 と同じ
<>等しくない"<>2"2 以外
>大きい">2"2 より大きい
<小さい"<2"2 より小さい
>=以上">=2"2 以上
<=以下"<=2"2 以下

引数「条件」に使用できるワイルドカードには次のものがあります。

パターン 説明 使用例 一致例
*任意の長さの文字"あ*"あ, あい, あいう
?任意の 1 文字"あ?"あい, あか, あき
~ワイルドカードの文字 * ? を検索する"あ~?~*"あ?*

使用例

セル「C2」の値と同じセルを数える。

=COUNTIF(B2:B5,C2)
10

「0」以外のセルを数える。

=COUNTIF(B2:B5,"<>0")
11

「エクセル」のセルを数える。

=COUNTIF(B2:B5,"エクセル")
12

「ワ」で始まるセルを数える。

=COUNTIF(B2:B5,"ワ*")
13

解説

引数「条件」は""で囲んで入力します。

引数「条件」に比較演算子を入力しない"エクセル""=エクセル"と同じ条件になります。

引数「条件」は大文字と小文字を区別しません。"=ABC"としたときはabcなどと一致します。

COUNT 関数」ではカウントされない次のものをカウントする方法を紹介します。いずれも「IS~関数」で判定して、その結果が「TRUE」のものを条件にすればカウントできます。

あああ

文字列をカウントするには「ISTEXT 関数」を使用します。文字列なら結果が「TRUE」になります。セル「B10」には空白文字が入っています。セル「B11」には何も入っていません。

=ISTEXT(B3)
18

その結果を引数「範囲」に指定して、引数「条件」を「TRUE」にします。

=COUNTIF(C3:C11,TRUE)
19

"10" や '10

特定の文字で囲まれている数字をカウントするには、まず「MID 関数」を使用して数字の部分を抽出します。その結果を「VALUE 関数」を使用して数字から数値に変換します。

"10" のとき
=VALUE(MID(B4,2,LEN(B4)-2))
'10 のとき
=VALUE(B4)
20

その結果を「ISNUMBER 関数」関数を使用して数値か判定します。数値なら結果が「TRUE」になります。

=ISNUMBER(C3)
21

その結果を引数「範囲」に指定して、引数「条件」を「TRUE」にします。

=COUNTIF(D3:D11,TRUE)

TRUE や FALSE

論理値をカウントするにはいろいろな方法があります。

「TRUE」や「FALSE」のみをカウントするなら条件を「TRUE」や「FALSE」にするだけです。

=COUNTIF(B3:B11,TRUE)
=COUNTIF(B3:B11,FALSE)

「TRUE」または「FALSE」をカウントするには「ISLOGICAL 関数」を使用します。論理値なら結果が「TRUE」になります。「OR 関数」を使用しても同じことができます。

=ISLOGICAL(B3)
=OR(B3,TRUE,B3,FALSE)
24

その結果を引数「範囲」に指定して、引数「条件」を「TRUE」にします。

=COUNTIF(C3:C11,TRUE)

空白

何も入っていないセルをカウントするには条件を = にするだけです。

=COUNTIF(B3,"=")

逆に何か入っているセルをカウントするには条件を <> にします。

=COUNTIF(B3,"<>")

空白文字が入っているセルをカウントするには「TRIM 関数」関数を使用します。空白文字が削除されます。セル「B10」には空白文字が入っています。セル「B11」には何も入っていません。

=TRIM(B3)
23

その結果を引数「範囲」に指定して、引数「条件」を = にします。

=COUNTIF(C3:C11,"=")

複数の条件を指定する

複数の条件に一致するセルを数えるには「COUNTIFS 関数」を使用します。これを使用しないでやる方法を紹介します。この方が柔軟な条件を指定できます。

AND 条件

複数の条件をすべて満たしているかは「AND 関数」を使用します。その結果を引数「範囲」に指定します。結果が「TRUE」のものを条件にすれば、条件をすべて満たしているセルを数えられます。

AND 関数」で、分類が「エクセル」で値が「100 以上」か判定します。

=AND(B3="エクセル",C3>=100)
14

AND 関数」で求めた結果が「TRUE」のものを条件にしてセルの数を数えます。

=COUNTIF(D3:D7,TRUE)
15

OR 条件

複数の条件を一つでも満たしているセルを数えるには「OR 関数」を使用します。その結果を引数「範囲」に指定します。結果が「TRUE」のものを条件にすれば、条件を一つでも満たしているセルを数えられます。

OR 関数」で、分類が「エクセル」または値が「100 以上」か判定します。

=OR(B3="エクセル",C3>=100)
16

OR 関数」で求めた結果が「TRUE」のものを条件にしてセルの数を数えます。

=COUNTIF(D3:D7,TRUE)
17
  • 目次
    • 構文
    • 使用例
    • 解説
    • 複数の条件を指定する